I use orbit downloader with K-meleon and it works well. But I noticed that after the installation of this download manager in firefox appears a small arrow that allows to download immediately a video or other stuff ( for example in sites like you tube there's a small arrow on the top of the video you're viewing). I'd like to know if there's a way to have this arrow also in k-meleon.
Thank you

hi dark, i hardly use firefox these days but i wanted to check this thing.
i enabled browser integration>firefox in orbit options and indeed it did add a small circular arrow on top of flv streams in youtube, i monitored the firefox folder to see if orbit added some kind of chrome or plugin to do that but i didn't find one.. so frankly i have no idea how they added that arrow and hence i can not say if it's possible to integrate in k-meleon.. my suggestion is to contact orbit's author for this.

for the mean time, here's a work around that should work O.K.

first go to your orbit's install path and look for this exe: grab.exe
doubleclick on grab.exe.. in grab ui, you will find a small yellowish button called 'action'. click on it and select preferences from the menu.

in the preferences dialog, click on the monitoring tab, select custom and then click "browser" button, browse to k-meleon.exe. click ok to save settings and exit grab.



or copy and paste this into notepad save as *.kmm extension and save in k-meleon's macros folder:





# K-Meleon Macros (http://kmeleon.sourceforge.net/wiki/index.php?id=MacroLanguage)

# ----------orbit monitor---------------------------------------------------------------------------
#
# Dependencies : -
# Resources : -
# Preferences : -
#
# ------------------------------------------------------------------------------------------------------------------

orbit{
menu = "Download by orbit";
exec("I:\\applications\\applications-x\\orbitdm\\Grab.exe " . $LinkURL);
}

orbit_BuildMenu{
# page menu(contextmenu)
setmenu(_Quick_Page,macro,"Orbit Monitor",orbit);
}

$OnInit=$OnInit."orbit_SetAccels;orbit_BuildMenu;";

# ------------------------------------------------------------------------------------------------------------------
$macroModules=$macroModules."LM;";


______________________________________
stop copying here

now this is very IMPORTANT:

you see the path set for orbit in the 3rd line of the script:
I:\\applications\\applications-x\\orbitdm\\Grab.exe

you must change that to your grab.exe location, if the path to grab.exe has a folder with spaces in its' name, then either use double quotes in the path name or use DOS 8.3 name.

this macro will add a new entry "orbit monitor" when you right click on a page, it will launch grab.exe which will monitor video files in k-meleon as set in it's preferences.

i tested it on youtube and streetfire videos and it works fine in capturing those videos.. so i think it should work ok on most sites.. goodluck

shot: http://necb.bizhat.com/orbitdm.jpg

note: grab.exe requires the page to be refreshed prior to capturing videos

i found the plugin and the chrome, they were in orbit's folder /addons/orbitff (f****** liberty!)
it is possible that it can be integrated with km.. i copied the plugin to kmeleon's plugins, and the jar+chrome to km's chrome.. renamed it but no arrow showed on top the vids.. so either it requires a skin inside the jar and.or the manifest needs to be edited for k-meleon.. i'll see if it can be done and come back to you.

sorry dark, i don't think it's doable(not by me anyways), the jar needs a skin inside.. and besides that, even if the arrow shows up on top vids, clicking it will not bring-up the orbit menu like in firefox.. it needs to be done from scratch for kmeleon.

i think the menu macro is pretty good, it does the job..

Thank you very much distrupted, your solution is perfect! but I've got a problem...the new entry "orbit monitor" doesn't apper when clicking whith the right button...does this macro work with k-meleon 1.5?

whoops! sorry.. that was completely my mistake, i built the menu on an existing menu macro(quick_note).. so ofcourse if you didn't have that macro, the orbit monitor won't show.

# K-Meleon Macros (http://kmeleon.sourceforge.net/wiki/index.php?id=MacroLanguage)

# ----------orbit monitor---------------------------------------------------------------------------
#
# Dependencies : -
# Resources : -
# Preferences : -
#
# ------------------------------------------------------------------------------------------------------------------

orbit{
menu = "Download by orbit";
exec("I:\\applications\\applications-x\\orbitdm\\Grab.exe " . $LinkURL);
}

orbit_BuildMenu{
# page menu(contextmenu)
setmenu(DocumentSave,inline,_Quick_Page);
setmenu(_Quick_Page,macro,"Orbit Monitor",orbit);
}

$OnInit=$OnInit."orbit_SetAccels;orbit_BuildMenu;";

# ------------------------------------------------------------------------------------------------------------------
$macroModules=$macroModules."orbit;";
___________________________________________________

this should work , sorry again.

now it works perfectly! thank you very much that's very usefull!

no..thank you! because i'm using it too

Hum, I don't have read this discussion at the beginning, and I just read it now.

I have already made an extension "Download with ... OrbitDownloader", but it uses orbitdm instead of grab.

But it's exactly the same. You're creating the wheel again

Here is my macro where I have inserted grab

# K-Meleon Macros (http://kmeleon.sourceforge.net/wiki/index.php?id=MacroLanguage)

# ---------- OrbitDownloader (An external download manager for K-Meleon) -------------------------------------------
#
# Needed files : orbit.exe
# Dependencies :
# Resources : -
# Preferences :
# ------------------------------------------------------------------------------------------------------------------

# In case of manual install, registry keys can't be found and menu is grayed
# To Bypass it, just fill the content of this variable the example value adapted
# to your config
# Example :
# $_Orbit_Path="\"C:\\Program Files\\OrbitDownloader\\orbitdm.exe\" %1"
# You must restart K-Meleon to take the modifications
# You have a shortcut to modify this value:
# SHIFT+ALT+T

$_Orbit_Path="";

# ---------- General -----------------------------------------------------------

$_Orbit_CommandLine="";

Orbit_Path{
$ext="kmm"; &getExtensionHandler; exec(sub("%1","macros\\Orbit.kmm",$cmdline));
}

_Orbit_CommandLine{
# try to get Orbit's command line from the Windows Registry
$__data=readreg("HKLM","Software\\Orbit\\path");
$__data==""?0:$__data=$__data."\\orbitdm.exe"." %1";
$_Orbit_CommandLine=$__data;
$_Orbit_CommandLine==""?$_Orbit_CommandLine=$_Orbit_Path:0;
}

$OnStartup=$OnStartup."_Orbit_CommandLine;";

# ----- MACROS

Orbit{
menugrayed=($_Orbit_CommandLine=="");
exec(sub("%1",$LINKURL,$_Orbit_CommandLine));
}

Grab{
menugrayed=($_Orbit_CommandLine=="");
$_Orbit_Grab=sub("orbitdm","grab",$_Orbit_CommandLine);
exec(sub("%1",$LINKURL,$_Orbit_Grab)." ".$LinkURL);
}

# ----- PRIVATE

_DownloadWith_Orbit_BuildMenu{
getpref(BOOL,"extension.downloadwith.loaded")?0:&__DownloadWith_Orbit_Default;
setpref(BOOL,"extension.downloadwith.loaded",true);
setmenu("Download &With",macro,"&Orbit Downloader",Orbit,0);
setmenu("Download &With",macro,"&Grab++",Grab,0);
setaccel("SHIFT ALT T","macros(Orbit_Path)");
}

__DownloadWith_Orbit_Default{
setmenu(LinkSave,inline,OpenWith);
setmenu(OpenWith,popup,"Download &With");
}

_DownloadWith_Orbit_KillPref{
delpref("extension.downloadwith.loaded");
}

$OnQuit=$OnQuit."_DownloadWith_Orbit_KillPref;";
$OnInit=$OnInit."_DownloadWith_Orbit_BuildMenu;";
# ------------------------------------------------------------------------------------------------------------------
$macroModules=$macroModules."Orbit;";


A+

---

Mozilla/5.0 (x11; U; Linux x86_64; fr-FR; rv:38.0) Gecko/20100101 Ubuntu/12.04 K-Meleon/76.0

---

Web: http://jujuland.pagesperso-orange.fr/
Mail : alain [dot] aupeix [at] wanadoo [dot] fr

---

Ubuntu 12.04 - Gramps 3.4.9 - Harbour 3.2.0 - Hwgui 2.20-3 - K-Meleon 76.0 rc

---

Edited 2 time(s). Last edit at 08/12/2008 08:03PM by JujuLand.

neat! thanks alain