Hi Folks: when surfing on facebook and clicking on a link that opens on the same page, you cannot go back to the same page you were before (physically it is, but the content has changed) as it has changes so much so that it si no longer the same page because it's filled with new things.

Proposition to avoid that: some kind of "never open any link on the same page, but alwas open it in a new tab, even if you just click on it and don't use right-click with "open link in new tab" ("econt-mode", see title).

There should be a button to turn that on and off (like in privacy bar), and there should be a list with url for those that mode can be activated. Either you have to add the current url to that list, and/or that mode would be active as soon and/or as long you press that button to open every click in a new tab.

Please discuss and implement asap ...

As someone who's in the habit of opening 95% of links in a new tab, by simply using middle-click instead of left-click, I find this method by far the best and most simple already :cool: Also much more flexible than needing to first change some switch for the few exception links.

http://kmeleonbrowser.org/wiki/faq#mouseaccels

But aside from that, don't know if changing left-click would be possible at all, and wonder what would happen (if anything at all) when left-clicking in other areas, for example for highlighting text or typing in an input box.
Then again, in KM76 Dorian has already changed the gesture-plugin to do multiple actions when left-clicking and *dragging" to the right side, depending if the mouse was over a link or image or text. They call this "superdrag". But guess such things really need "plugins" and a dev to create them.

Ah yes, and there's also the prob that lots of "links" on such "complicated" websites are in reality javascripts, not really links. Many of those can't be opened in new pages anyway.



Edited 2 time(s). Last edit at 02/09/2016 10:43AM by siria.

You did not get the point, sorry to tell!

The thing is to disable the function that left click opens in the same window/tab. Instead it should be replaced by "left click is directly opening a new tab for that link". This is some kind of temporary setting or a setting for a special url (that you can declare).

It would be nice with a button in the style of the privacy bar: green is normal behaviur, red would be "every normal left click opens a new tab instead of opening the link in the same tab". You should be able to turn that on and off for the foreground page and it keeps active for that page until you turn it off or close that tab. But you should also be able to declare in advance this behavouir for some special urls, meaning: if you open i.e. www.facebook.com (but only www.facebook.com, and not any page below (as www.facebook.com/xyz)) that behaviour should be set automatically when opening that page.

The aim is to avoid going to a new page by left click but always stay on that page. The reason for that is that you cannot go back and find the same contents as before, but everything is filled up with new things even if it's the same page.

The reason for it is to avoid clicking somewhere unintentionally and leaving the page. It is to avoid that erroneous clicks cause damage of leaving the page even if it was not intended.

If you click to anything on that page, the normal behaviour of going to that page in the same tab must mandatorily be disabled (to never leave that page by left clicking on any link) and replaced by opening that link in a new tab on left click.

That's it - nothing less and nothing more.

Btw.: just stopping scripting cannot be a solution als fb is not working without scripting.



Edited 9 time(s). Last edit at 02/10/2016 10:07AM by Voltaire.

And I still think too it's you who misunderstands
But doesn't matter, because still don't know anyway how and if it could be done at all, on the mouse side. At least that would require dev-skills, and personally am just a user like you, just more experienced with macros and where to find some settings.
Keep in mind that my view doesn't count any more than yours, and more skilled people may have different views.

And in general Ijust find it very problematic to mess with left-clicks. From how you made it very clear now, the issue isn't really how a link gets opened by default (=> just make it a reflex to click middle-button by habit), but how to make things as foolproof as any possible to avoid accidents.
The prob is that left-clicks must already handle too many different tasks depending on context. It's not trivial at all to mess with that. And certainly has a much higher potential of 'accidents' than just using a middle-click by default, so things could get rather worse than better.

Why not try it at least for awhile with middle-clicks, after changing the default setting for them??

You'd notice it becomes a finger reflex very quickly, if you're someone like me who opens almost all links in new tabs anyway. Must really make a conscious effort now to use the LEFT button on a link, so no accidents probable.

And if you want to open JAVASCRIPT "links" in a new tab, there's no chance for that anyway. Most of those are not links at all, but scripts that only work when running on the current page.

Something completely different, what I could imagine much easier is to manipulate not the mouse settings but the page source itself:
Have a little macro running after every page load that checks the current URL and if matching your conditions, it injects a little script that adds a "_blank" target to all links on the current page...
Then the page itself tells the browser "On clicking open this link in a new page". Still to consider some special probs and no idea about js-links, but for "normal" links that should work.
(Others any opionions? or macros..? :cool

Quote
siria
Something completely different, what I could imagine much easier is to manipulate not the mouse settings but the page source itself:
Have a little macro running after every page load that checks the current URL and if matching your conditions, it injects a little script that adds a "_blank" target to all links on the current page...
Then the page itself tells the browser "On clicking open this link in a new page". Still to consider some special probs and no idea about js-links, but for "normal" links that should work.
(Others any opionions? or macros..? :cool

I was thinking of something like that ... ... It does not matter on what level the left-click is caught and diverted to open a new tab and not a link on the same tab in the same window.

And something else: I don't have a "middle click" in the two buttons (left/right) on my note- and netbooks!



Edited 1 time(s). Last edit at 02/10/2016 09:08PM by Voltaire.

That's why the first thing I do with a notebook is getting a mouse for it :cool: It's just so much handier! And using it only at home anyway. On the street it would be another thing of course.

But did you try to emulate a middle-click?
For example I have a synaptics touchpad, and that offers a bunch of settings. On the buttons/keys tab for example it's possible to define the left-button to act as middle-button! Since I can just "tap", which works as left-click too, this seems an acceptable solution for my needs.
But perhaps should add that this notebook is not used on the web, only for a bit offline testing of newer KM and other offline use, so not sure about real life use :cool:

Or some other possibilities?
http://www.google.de/search?q=%22middle+click%22+touchpad&btnG=Suche&num=30&nfpr=1&gbv=1

This works, but I find it a bit 'different' and won't use it after this test. Put the following in your Accelerators file.

LButton = ID_OPEN_LINK_IN_NEW_TAB

If you do this, then you will need some method to simulate the normal method. i.e. you won't be able to post in the forum and other things that require the same tab.

Quote
JamesD
This works, but I find it a bit 'different' and won't use it after this test. Put the following in your Accelerators file.

LButton = ID_OPEN_LINK_IN_NEW_TAB

If you do this, then you will need some method to simulate the normal method. i.e. you won't be able to post in the forum and other things that require the same tab.

And that's why it has to be turned on and off as easy as the "privacy bar buttons".

Normal usage would then be:

- normal state: turned off.
- visiting fb (or else): after page has first loaded once, turn it on (from then, all the clicks are diverted to open an new tab).
- if you want to click on a link that has to be opened in the same tab: turn it off (on the button in the toolbar), click on that link, and turn it on again (again click on the button in the toolbar).
- the setting has to be valid only for the tab in foreground; so if you close the tab the setting is "gone" (and turned off again for the other tabs), as it's not the same tab you come to ...

So the question now is: how to put that in a toggle-on/off-button in a toolbar ...



Edited 3 time(s). Last edit at 02/11/2016 10:59AM by Voltaire.

Then:

LButton = macros(lbutton_open)

and the macro for lbutton_open, check for a preference value, if true, open, if false, opennew.

Note: this is not an actual macro, just a functionality one example.



Edited 1 time(s). Last edit at 02/11/2016 04:07PM by JohnHell.

JohnHell

Quite right. Been working on that for four hours. Almost done.

If not too many errors when I try it, it should be ready right after lunch. I hope.

The menu does not show the check mark and the image is wrong on the button. But it does work? Sorry I can't make better. Too old, I guess.

Edit:
I have made some changes. The menu works now, but I don't remember how to select vertical parts of the png file for the button. I added a fix for when there is not a link, but that does something bad to buttons for posting. Needs another fallback somehow.



KMLClick.kmm

#  K-Meleon Macros (http://kmeleon.sourceforge.net/wiki/index.php?id=MacroLanguage2)
#  
# ---------- KMLClick.kmm
# ---------- K-Meleon Macro Language  External Listbox demonstrater ---------------
#
# Dependencies        : - main.kmm 
# Reference           : - http://kmeleonbrowser.org/forum/read.php?4,137550,137595#msg-137595
# Preferences         : - "kmeleon.plugins.macros.kmlclick.diverted"
# Version             : - 0.3   2016_02_11
# --------------------------------------------------------------------------------

_KMLClick_Toggle {
   menuchecked = getpref(BOOL, "kmeleon.plugins.macros.kmlclick.diverted");
   togglepref(BOOL, "kmeleon.plugins.macros.kmlclick.diverted", true, false);
   getpref(BOOL,"kmeleon.plugins.macros.kmlclick.diverted") ? $__img = 0 : $__img = 1;
   #alert( getpref(BOOL,"kmeleon.plugins.macros.kmlclick.diverted"), "Diverted img ".$__img, INFO);
   setcmdicon( "macros(_KMLClick_Toggle)", "check.png[".$__img.",32.32]" );
   statusbar("Left Click changed ".$__img);
}

KMLClick_Click {
   if ($LinkURL != "" ) {
   getpref(BOOL,"kmeleon.plugins.macros.kmlclick.diverted") ?  opentab( $LinkURL ): open( $LinkURL );
   }
}

_KMLClick_BuildMenu {
   # add another option to Tools menu
   setmenu("&Tools", macro, "Left click diverted", _KMLClick_Toggle, "Misc");
} 

_KMLClick_BuildButton {
   $_KMLClick_TTip = "Left mouse click diverted" ;
   addtoolbar("KMLClick") ;
   addbutton("KMLClick", "macros(_KMLClick_Toggle)", "Left click diverted", $_KMLClick_TTip);
   getpref(BOOL,"kmeleon.plugins.macros.kmlclick.diverted") ? $__img = 0 : $__img = 1;
   setcmdicon( "macros(_KMLClick_Toggle)", "check.png[".$__img.",32,32]" );
}  

_KMLClick_SetAccels{
setaccel("LButton", "macros(KMLClick_Click)");
} 

## - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
$OnInit=$OnInit."_KMLClick_BuildMenu;_KMLClick_SetAccels;";
$OnSetup=$OnSetup."_KMLClick_BuildButton;";
$macroModules=$macroModules."KMLClick;";

Edited 1 time(s). Last edit at 02/11/2016 07:40PM by JamesD.

JohnHell

We had a good idea, but it won't work. Once one changes the LButton there is not a way to un-change it. We can direct it only in the ways covered by command IDs and there is not one for 'as before'.

Yes, that is what I expected in my initial thought, that we can't dynamically change an accel through setaccel.

The intention here is to let the user edit his profile accel.cfg and add/change lbutton to what I wrote:

LButton = macros(lbutton_open)

(I'll try the macro now, I was offline all these hours)

@JamesD, I was wrong. It can be changed and I think I misunderstood you above.

EDIT: I know how to set icons in toolbars but via toolbars.cfg, with macros... it is another history :-? Siria could tell.

This works, but fix it, I'm not the best with macro coding guidelines:

#  K-Meleon Macros (http://kmeleon.sourceforge.net/wiki/index.php?id=MacroLanguage2)
#  
# ---------- KMLClick.kmm
# ---------- K-Meleon Macro Language  External Listbox demonstrater ---------------
#
# Dependencies        : - main.kmm 
# Reference           : - http://kmeleonbrowser.org/forum/read.php?4,137550,137595#msg-137595
# Preferences         : - "kmeleon.plugins.macros.kmlclick.diverted"
# Version             : - 0.3   2016_02_11
# --------------------------------------------------------------------------------

_KMLClick_Toggle {
   menuchecked = getpref(BOOL, "kmeleon.plugins.macros.kmlclick.diverted");
   togglepref(BOOL, "kmeleon.plugins.macros.kmlclick.diverted");
   $_KMLClick_status = getpref(BOOL,"kmeleon.plugins.macros.kmlclick.diverted");

	if($_KMLClick_status == "true"){
		setaccel("LButton", "macros(KMLClick_Click)");
		$__img = 1;
	}else{
		setaccel("LButton", "");
		$__img = 0;
	}

   setcmdicon( "macros(_KMLClick_Toggle)", "check.png[".$__img.",32.32]" );
   statusbar("Left Click changed ".$__img);
}

KMLClick_Click {
   if(($LinkURL != "" ) and (index($LinkURL,"javascript") == -1) and (index($LinkURL,"#") != length($LinkURL)-1)){
	opentab($LinkURL);
   }else{
	open($LinkURL);
   }
}

_KMLClick_BuildMenu {
   # add another option to Tools menu
   setmenu("&Tools", macro, "Left click diverted", _KMLClick_Toggle, "Misc");
} 

_KMLClick_BuildButton {
   $_KMLClick_TTip = "Left mouse click diverted" ;
   addtoolbar("KMLClick") ;
   addbutton("KMLClick", "macros(_KMLClick_Toggle)", "Left click diverted", $_KMLClick_TTip);
   getpref(BOOL,"kmeleon.plugins.macros.kmlclick.diverted") ? $__img = 0 : $__img = 1;
   setcmdicon( "macros(_KMLClick_Toggle)", "check.png[".$__img.",32,32]" );
}  

_KMLClick_SetAccels{
setaccel("LButton", "macros(KMLClick_Click)");
} 

## - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
$OnInit=$OnInit."_KMLClick_BuildMenu;_KMLClick_SetAccels;";
$OnSetup=$OnSetup."_KMLClick_BuildButton;";
$macroModules=$macroModules."KMLClick;";

Edited 5 time(s). Last edit at 02/12/2016 11:45PM by JohnHell.

I fixed a couple of dumb mistakes I found (above code) when I was trying to imagine how to use setbuttonimg :-? but no clue.

@ JohnHell

Your idea is right. Mine not so good. I am trying to fix image on button, Siria could put on Privacy Bar, I guess.

Add configure for tab or window and open in background?

EDIT: the window or tab is not needed as when tabbed browsing is not enabled, it opens a new window instead.

Ufff that will need change to INT preference, at least. And the menu items. Or adding a new preference. Is it really needed? xD

Anyway, I found a glitch and it is that playing with lbutton accel affects INTRO key functionality in submit forms (as search fields) as INTRO works there as a click.

Another glitch is for "anchored" URLs where in background runs an onclick function. That onclick won't work.

After post this I'll fix the code above with a new change or javascript:function(); urls won't work.



Edited 1 time(s). Last edit at 02/12/2016 11:50PM by JohnHell.

Brilliant idea! Setting the accel to "" !
Always assumed the only alternative would be to set the accel to do null, expecting KM to do nothing at all anymore. But "" really seems to unregister the shortcut again, a break-through idea for me Also very interesting that even with that shortcut active, toggling buttons and highlighting text etc. all still seems to work, so far the only exception seem to be page buttons. And javascript-links of course.

And thanks for considering me a button-expert but frankly am only doing the same as everyone: take a previous macro as template and change commands. Hmm, and would have to research again to know for sure, but frankly that dot between 32.32 looks slightly suspicious...

The PrivBar would IMO not be an ideal place for it, default-buttons way too broad. Of course macros don't all need single-button toolbars, they can just as well be added to any existing one. Prob as usual, only the user himself knows which ones he has visible.

What I'd like for users is an option to use "checkbutton" instead of changing images :cool: Probably a 50/50 preference among users, thinking of past discussions.

Well, just did my own quick function test, and then couldn't resist playing again, sigh. Had an idea, now wondering if this pause-gimmick would have any worth, or even works right enough?

(code is a bit odd only due to lazyness, not planning to jump in too deeply here, so no buildmenu yet - just suggestions below)

$OnStartup=$OnStartup."KMLClick_Toggle;";
$_lbtON=-1; $_lbt_dclick=0;

KMLClick_Toggle{
menuchecked=$_lbtON==1;
setaccel("CTRL LButton","macros(KMLClick_pause)");
$_lbtON=-$_lbtON;
if ($_lbtON==1) setaccel("LButton","macros(KMLClick_Click)");
else setaccel("LButton","");
}

KMLClick_Click{
if ($LinkURL>"")
index($LinkURL,"javascript:")==0 ? open($LinkURL): opentab($LinkURL);
else 0;
}

KMLClick_pause{
# for shortcut Ctrl+LButton and/or for toolbar button (with the permanent toggle only on button-context-menu):
$_lbtON=-1; setaccel("LButton", "");
if ($_lbt_dclick==1) {$_lbt_dclick=2; alert("","Left-Click Macro ".$off,INFO);}
if ($_lbt_dclick==0) {$_lbt_dclick=1; settimer("KMLClick_enable",3,free);}
}
KMLClick_enable{
if ($_lbt_dclick==1) {$_lbtON=1; setaccel("LButton","macros(KMLClick_Click)");}
$_lbt_dclick=0;
}

-----
ah yes, anchors! Not quite as simple all those exceptions...
But the conditions should be if index!=0, that means if the link STARTS with the index string.

siria

Thank you for your good eyes. Period instead of comma, eh? Four hours trying to fix the button image and my old eyes did not catch my typo.

Like you, I don't like the image that I have used. However it is available in skins\shared. I would prefer something like this:

if I could make it two ways, flat and depressed.

Edit: Button code is for horizontal image and current is vertical. I must get better image.


Tried to post yesterday but every time it seemed the guru was out.

JohnHell

Great idea. That is thinking outside the box.

This is my latest model code. Please feel free to add conditions, exceptions, etc. as required. I will make the statusbar look better in next release

KMLClick.kmm

#  K-Meleon Macros (http://kmeleon.sourceforge.net/wiki/index.php?id=MacroLanguage2)
#  
# ---------- KMLClick.kmm
# ---------- K-Meleon Macro Language to switch between  -- 
# ---------- left button to open in new tab or normal ----
#
# Dependencies        : - main.kmm 
# Reference           : - http://kmeleonbrowser.org/forum/read.php?4,137550,137595#msg-137595
# Preferences         : - "kmeleon.plugins.macros.kmlclick.diverted"
# Version             : - 0.4   2016_02_12  JamesD's coding of JohnHell's idea
# --------------------------------------------------------------------------------

_KMLClick_Toggle {
   menuchecked = getpref(BOOL, "kmeleon.plugins.macros.kmlclick.diverted");
   togglepref(BOOL, "kmeleon.plugins.macros.kmlclick.diverted");
   $_KMLClick_status = getpref(BOOL,"kmeleon.plugins.macros.kmlclick.diverted");

	if($_KMLClick_status == "true"){
		setaccel("LButton", "macros(KMLClick_Click)");
		$__img = 0;
	}else{
		setaccel("LButton", "");
		$__img = 1;
	}

   setcmdicon( "macros(_KMLClick_Toggle)", "check.png[".$__img.",32,32]" );
   statusbar("Left Click changed ".$__img);
}

KMLClick_Click {
   if(($LinkURL != "" ) and (index($LinkURL,"javascript") == -1)){
	opentab($LinkURL);
   }
}

_KMLClick_BuildMenu {
   # add another option to Tools menu
   setmenu("&Tools", macro, "Left click diverted", _KMLClick_Toggle, "Misc");
} 

_KMLClick_BuildButton {
   $_KMLClick_TTip = "Left mouse click diverted" ;
   addtoolbar("KMLClick") ;
   addbutton("KMLClick", "macros(_KMLClick_Toggle)", "Left click diverted", $_KMLClick_TTip);
   setcmdicon( "macros(_KMLClick_Toggle)", "check.png[1,32,32]" );
} 

_KMLClick_InitPref {
setpref(BOOL,"kmeleon.plugins.macros.kmlclick.diverted", false);
} 

## - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
$OnInit=$OnInit."_KMLClick_BuildMenu;_KMLClick_InitPref;";
$OnSetup=$OnSetup."_KMLClick_BuildButton;";
$macroModules=$macroModules."KMLClick;";

Edited 1 time(s). Last edit at 02/13/2016 11:30AM by JamesD.

Let me abuse of the wiki system. To find what was removed (red text) and what was added (green text), it may help, even it mixes a little the removed and added positions, to find out the changes:

http://kmeleonbrowser.org/wiki/diff;MacroDevKMLClick?version=2

The green in this diff are mines, after your posting above.

We won't be able to delete wiki pages, but would work as kind of a CVS for group developing of macros.

If you want to see the last version, just remove the diff; and ?version=X from the URL:
http://kmeleonbrowser.org/wiki/MacroDevKMLClick



Edited 3 time(s). Last edit at 02/13/2016 03:02PM by JohnHell.

Interesting idea with the wiki, but please let's move this thread to extensions forum anyway. Attaching files is so much easier than going over wiki first. We can still update the wiki additionally, if you prefer it to tools like examdiff.

Have uploaded version 0.6 now.
(am afraid the wiki won't help much for 06, too much changed :cool

- Added another menu option to show the button permanently pressed.
- Got the unpressed button image working, but differently as you might expect :cool: (misunderstanding: icon-numbering works horizontal not vertical)
- If there is no Link under the mouse at all, the macro doesn't run "open()"
- Keeps user settings between sessions
- Lots of little cosmetic stuff, added macroinfo, changed a few statusbar and menu texts, var names and handling etc

And think the toolbar should have a similar name as the menu, and perhaps the whole macro/kmm too more intuitive ("KML".. =confusing)



Edited 2 time(s). Last edit at 02/14/2016 03:09PM by siria.

siria

Agree, we should go to extensions. Where is your version 6?

I just finished my version 6. You can find it here.

https://dl.dropboxusercontent.com/u/1522294/KMLclick.7z

mine is here:
http://kmeleonbrowser.org/wiki/MacroDevKMLClick

Ah darn, I was afraid we might work parallel! Sigh...



Edited 1 time(s). Last edit at 02/14/2016 03:32PM by siria.

New thread in Extensions is here: http://kmeleonbrowser.org/forum/read.php?9,137646

I am sorry, but I don't understand how I am to do the wiki bit.

I will not be able to work more, right now. Use any part of my stuff and change what is needed to be changed.

I had to split the macro for toggle so the correct check marks would show in menu. Repeating the image when shown checked does not work.



Edited 1 time(s). Last edit at 02/14/2016 03:02PM by JamesD.

Ah, now I finally understand why you started using 2 macros for the same task!

That's one possiblity yes.
Another would be not to use setcmdicon (which sets menu+button), but instead only setbuttonimg (which sets only the button).
Or a 3rd possiblity, which my version is currently trying out: showing the disabled icon in the menu instad of the active one (using setcmdicon after each toggle)

Oh well... couldn't resist to play with that settimer function again!
Just think it would be really handy, saving the need to toggle 2x manually:
1x click on button:
diversion is off, button shows the history clock ("countdown"), and after 2 seconds the timer automatically enables the diversion again.
Doubleclick on button (2x in 2sec): diversion is permanent off

But now noticing another prob:
Could it be that setaccel only works 2-3x during a session and then stays disabled???
Tried in KM75.1 and 76, and to be sure tried your macro too in 75.1. Not the slightes idea what's happening with that? *confused*

My kmm v0.7 is attached in the other thread, thanks for creating:
http://kmeleonbrowser.org/forum/read.php?9,137646

(still just test version, for the moment kept the dummy icons)

Another solution if you have no middle click button is to use Control + left click. It's pretty easy to get used to I think