Here is a little macro to enable integeration with FreeDownloadManager.
It was made because on my system, the suggested way to enable the Netscape integeration doesnt work, I dont know about others.
On the other hand, it uses far less resources as the npfdm.dll Netscape plugin.
Create a file in macro folder:
fdm.kmm
Copy paste the following Code:
# K-Meleon Macros (http://kmeleon.sourceforge.net/wiki/index.php?id=MacroLanguage)
# ---------- FreeDownloadManager --------------------------------------------------------------------
#
# Dependencies : main.kmm (Go), sendto.kmm (menus)
# Resources : -
# Preferences : -
#
# ----------------------------------------------------------------------------------------------------
FDM_OpenLink{
macroinfo=_("Open link in FreeDownloadManager");
$_FDM_Open=$LinkURL; &_FDM_Open;
}
# ----- PRIVATE
_FDM_Open{
# try to locate the Program Files directory:
$__data=readreg("HKLM","\\Software\\FreeDownloadManager.ORG\\Free Download Manager\\Path");
$__data==""?$__data="C:\\"._("WINDOWS\\WinTE\\Internet\\FDM"):0;
# fallback command line:
$_FDM="\"".$__data."\\fdm.exe\" %1";
# try to get IE's command line from the registry:
$__data=readreg("HKCR","Applications\\fdm.exe\\shell\\open\\command\\");
# catch invalid IE7 registry data:
index($__data,".")>index($__data,"%1")?$__data="":0;
$__data==""?0:$_FDM=$__data; exec(sub("%1",urldecode($_FDM_Open),$_FDM));
}
_FDM_BuildMenu{
index($macroModules,";SendTo;")>-1?&_FDM_BuildMenu_SendTo:&_FDM_BuildMenu_Default;
}
_FDM_BuildMenu_Default{
$__m="Open In &FreeDownloadManager";
setmenu(LinkOpenExternal,macro,$__m,FDM_OpenLink);
}
_FDM_BuildMenu_SendTo{
$__m="&FreeDownloadManager";
setmenu($_SendTo_Link,macro,$__m,FDM_OpenLink);
}
_FDM_SetAccels{
setaccel("CTRL ALT F","macros(FDM_OpenLink)");
}
$OnInit=$OnInit."_FDM_SetAccels;_FDM_BuildMenu;";
# ------------------------------------------------------------------------------------------------------------------
$macroModules=$macroModules."FDM;";
NOTES:
Line 22 shows the FDM install path on my system, you have to change it according to the path of FDM on your system.
Line 26 contains registry path to pick:
HKCR","Applications\\fdm.exe\\shell\\open\\command\\"
So you have to create this registry with your path or use the following .reg script (beware to change the FDM install Path according to your system):
REGEDIT4
[HKEY_CLASSES_ROOT\Applications\fdm.exe\shell\open\command]
@="\"C:\\WINDOWS\\WINTE\\INTERNET\\FDM\\FDM.EXE\" %1"
NOTE3:
Using the FDM plugin npfdm.dll increses the load time of K-Meleon, this doesnt.