Extensions :
K-Meleon Web Browser Forum
Often I am in need to copy more than links (URLs) from a page. That is, to select multiple links , right click and copy links, to paste in some test file.
Currently there is no such option in K-Meleon, if I select multiple links and right click > copy link URL, only the first line or the link is get copied.
Is there a macro or something?
UPDATE
Here's a working macro, slightly belated... A major bugfix and overhaul of James second macro below (link2clipb), which was based on the bookmarklet Dorian posted below, but had copy errors due to the forum suppressing all the original [ i ] in the code!
It's now link2clip version-2, and got a menu line, and an option to create the list with or without additional link NAMES.
And it shows the list after creation in a popup prompt, not just silently in the clipboard. This prompt is also a workaround for ancient KM1.5.4 and 74 which cannot put the list into clipboard automatically by JS. But users can always copy huge text blocks from this input field :-)
The keyboard shortcut is NOT added by default anymore, only prepared if anyone wants it.
There are a few more customizing options for users in the code directly, marked with **USERCONFIG**, but those will only work after restarts.
Attention Windows98:
the system silently crops those javascript prompt fields at max 32kB size.
And Win98 even crashes the browser if putting more than 160.000 characters into such an input (here rather "output") field. But win98 is amost non-existant today, and additionally such GIANT link lists either, so no real prob. If really someone needs it, help yourself by cropping the output in the prompt line, e.g. to linklist.substr(0,40000)
Installation: put the attached kmm-file into a macros folder and restart.
UN-installation: remove the file again, no traces left.
========= Original post long ago / IGNORE
Hm, can only think of more or less workarounds, but not marking several links at once, sorry.
Perhaps a little macro with an own shorcut or a menu that collects Link URLs one by one into a clipboard list (if setclipboard works again in newer KM versions). Something like Alt-Shift-Middleclick... click... click... click... and at the end you open your text tool and hit Ctrl-V (the most complicated task for this would be to decide for a shortcut ;-))
Or the macro could write the list into a new ini-file, but that has a structure with keys and a values. Or it could write it into a new tab (somewhere I made a macro that does this to show some help instructions, so could look up there how it works).
Or perhaps the native list for All links already helps anything? (View>Links). It could probably be extended to show also the URLs, not just the titles.
Which KM version are you using?
Edited 6 time(s). Last edit at 07/13/2020 02:52PM by siria.
Attachments:
links2clip_screens.png (33.5 KB)
links2clip.kmm (4.7 KB)
If I correctly understand the need, then this might help. This macro adds an option, "Add link to storage", to the LinkSave menu and to the Tools menu an option called "Send stored links to clipboard". With it, one can add any desired link URL to the list, one at a time, and then move the complete list to the clipboard so it can be pasted.
linkstore.kmm
Edited 2 time(s). Last edit at 08/15/2015 11:43PM by JamesD.
Yep, exactly my thought too
Just can't resist... This:
_linkstore_Add {
$_linkstore_tempclip = getclipboard();
setclipboard( "" );
id(ID_COPY_LINK_LOCATION);
$_linkstore_thislink = getclipboard();
$_linkstore_alllinks = $_linkstore_alllinks."\n". $_linkstore_thislink ;
setclipboard( $_linkstore_tempclip );
}
needs no unnecessary complications, just:
_linkstore_Add {
macroinfo="Collect links in a list. When finished click menu Tools > Send stored links to clipboard";
$_linkstore_alllinks = $_linkstore_alllinks."\n". $LinkURL ;
}
Edited 1 time(s). Last edit at 08/15/2015 11:20PM by siria.
siria
I added that line. Thanks
Yeah, but why not use $LinkURL for collecting, instead of all that clipboard juggling...?
For further improvement the send-macro could offer to reset the stored list and start a new one. The alert box is quite handy for this, just add yes-no-cancel buttons and a question like "Delete stored list now?"
And perhaps prepare a keyboard shortcut (keys free choice up to Wasi as requester :cool. At least as a howto-note, for users to add themselves to accels.cfg:
# xxxx = macros(_linkstore_Add)
Edited 2 time(s). Last edit at 08/16/2015 09:13AM by siria.
Because I simply did not think about it. Good suggestions. I will have a look at updating the macro.
siria
Using $LinkURL and offering to clear the storage have been added. I am very unsure about keyboard shortcut keys. What would happen if they were used when not on a link? I did not include them.
Thank you for the excellent suggestions.
linkstore.kmm
Yep same prob here, that's why I want users to choose it themselves
But we can still tell them HOW to do it themselves, by at least adding a hint in the kmm (or even prepare a commented setaccel):
# Keyboard shortcut - HOWTO: choose your preferred keys and add a line to your accels.cfg, using this macro name:
# xxxxxx = macros(_linkstore_Add)
I still remember it took me an endless struggle years ago to just figure out which are the command names in macros! Long, long ago...
Well, and now I'd merge the alert box and the confirmation box into one, and shorten overwritable variables:
_linkstore_Send {
setclipboard( $_linkstore_alllinks );
$_x=getclipboard();
$_x=confirm("Clipboard has ".$_x."\n\n-----------\nClear the stored list now?", "Link list copied / Reset list?", YESNO, QUESTION );
$_x== "YES" ? $_linkstore_alllinks = "selected links list: " : 0;
}
My question is not about the user's choice of keys. It is what is in $LinkURL if the keys are pressed and the cursor is not on a link. The menu is only available if the cursor is on a link when the right click occurs.
I had completely forgotten that one can have multiple lines in the message argument of the confirm statement. Another good catch by you.
I tightened up the code a bit more and added one small visual appearance bit to the list title.
I wonder if WasiAzeem has been back to check on this?
linkstore.kmm
It simply is empty. So this macro adds an empty line, which may later indicate to the user that something was wrong.
Another possibility would be to add a check to the macro: $LinkURL=="" ? alert(...)
Thinking about it, a possible check could also include to check for other error possibilities, like empty javascript links if JS is off etc (what whas it again that this usually shows in the statusbar?). Or looking at twitter com, the sign-on button changes the mouse cursor into the link symbol (hand), but there is no link at all...
Anyway, in my opinion a shortcut is just a lot faster for adding a dozen close neighbor links instead of needing the context menu each time and finding the correct line in it each time (my own context menus tend to be slightly extended :cool:)
(PS: I would have put getclipboard() directly into the confirmation too, but somewhere in the old macrolanguage wiki is a warning to be careful with certain commands directly inside modal window commands (alert/confirm etc.) due to some bug. It may not exist anymore or only affect certain commands, no idea, but since I can never remember the exact conditions, usually just stick to plain variables inside)
OK, I have a control keyset included. I very seldom use them myself. That would require me to remember which keys to use, and at my age remembering is a chancy thing at best.
linkstore.kmm
Hm... alert has no title...
The shortcut is a misunderstanding, I never meant to *activate* it, only have a # line prepared as example! Or the above hint for accels.cfg in a comment line. Basically we fully agree that shortcuts are a bit prone to conflict with others.
Thanks for such a quick and detailed replies. Just saw these and need to read all these, will come back very soon
KM 1.6 and KM 75 both, I am in a phase of switching to 75 from 1.6
Many thanks. Versin 1.5 works and it is quite close to what I need, thanks.
WasiAzeem
Glad we could help you. Thank you for your reply.
Using some random bookmarklet, I've made this:
It get links in the selection, or all links if no selection.
OK, I admit that I am lost. Please find me.
What does this mean? This was for all links. I don't know how to select multiple links.
links2clipb.kmm
Edited 1 time(s). Last edit at 08/19/2015 12:18PM by JamesD.
You don't select link. It only search for links in the selected text.
You get it all the time or on specific pages?
Thanks. Now I understand that.
I just got the same messages for the area 'Home/News' through 'Development' at the top of this thread. So that is two times. Once with no selection and once with a selection.
I love K-Meleon and I love you guys.
Just came across this randomly again, and wondered how that selection thing works in JS. But the code was too confusing, so started fiddling with it... as usual... oh well ;-) After awhile realized: the plain bookmarklet works if copied from a quote post, but the macro had a bug. Obviously the forum was culprit: it's eaten all [ i ] in the visible code! Only the posts 'source' code has the full original. Old prob, happened a couple times before, am meanwhile aware of that trick.
But couldn't stop there, wanted a visible output, and an option for names, and... (the usual again ;-)
Have now made an update of this second macro (links2clip):
The updated macro links2clip-v2 is now available above, on top of this page, in the second post. And more description about it. For example this output box can also be suppressed.
Thanks for this new unfixable Phorum nightmare to my dreams.
Thankfully, can be escaped any square bracket by adding a backslash [i] in the post edit or prior to posting [code]
Edited 1 time(s). Last edit at 07/13/2020 01:40PM by JohnHell.
HA - great trick! Another just perfect solution, finally
But then again, this creates another catch: now the post's original code, as seen when hitting the "quote" button, is not original anymore and will be 'buggy'
And the other 'almost perfect' workaround, to check "Disable BBcode" and "Disable Smileys" in the header above, does keep the original code original AND the visible output correct too.
But also has a killer catch : stuff like [quote] or [code] or smilies or text colors don't work either, and will show up literally
Oh well, guess we'll have to consider in each single case which escape method to use. For my previous sentence here, your backslash method \[i] is just perfect, thanks. While for posting larger code blocks, they should probably be posted with the checkboxes above marked. Was aware of that before, but wanted to include the quotes, and was in a hurry. Next time may post such code blocks alone in a single post, and rest of talk in a second post.
(_howto_ HowTo post CODE in forum, escape square brackets, smilies and other bbcode syntax)
Edited 3 time(s). Last edit at 07/13/2020 02:27PM by siria.
Code blocks could be used escaped (after all, forum users shouldn't quote to copy, but copy directly the code block) and offer a file for download (those of us who can attach), even though it doubles the post size and wishing SourceForge keeps forgiving us for the space usage.
That is the reason it is a new Phorum script nightmare
Edited 1 time(s). Last edit at 07/13/2020 03:58PM by JohnHell.
All about K-Meleon extensions.
option to copy multiple selected links
Posted by:
WasiAzeem
Date: August 15, 2015 03:58PM
Often I am in need to copy more than links (URLs) from a page. That is, to select multiple links , right click and copy links, to paste in some test file.
Currently there is no such option in K-Meleon, if I select multiple links and right click > copy link URL, only the first line or the link is get copied.
Is there a macro or something?
Re: option to copy multiple selected links
Posted by:
siria
Date: August 15, 2015 05:23PM
UPDATE
Here's a working macro, slightly belated... A major bugfix and overhaul of James second macro below (link2clipb), which was based on the bookmarklet Dorian posted below, but had copy errors due to the forum suppressing all the original [ i ] in the code!
It's now link2clip version-2, and got a menu line, and an option to create the list with or without additional link NAMES.
And it shows the list after creation in a popup prompt, not just silently in the clipboard. This prompt is also a workaround for ancient KM1.5.4 and 74 which cannot put the list into clipboard automatically by JS. But users can always copy huge text blocks from this input field :-)
The keyboard shortcut is NOT added by default anymore, only prepared if anyone wants it.
There are a few more customizing options for users in the code directly, marked with **USERCONFIG**, but those will only work after restarts.
Attention Windows98:
the system silently crops those javascript prompt fields at max 32kB size.
And Win98 even crashes the browser if putting more than 160.000 characters into such an input (here rather "output") field. But win98 is amost non-existant today, and additionally such GIANT link lists either, so no real prob. If really someone needs it, help yourself by cropping the output in the prompt line, e.g. to linklist.substr(0,40000)
Installation: put the attached kmm-file into a macros folder and restart.
UN-installation: remove the file again, no traces left.
========= Original post long ago / IGNORE
Hm, can only think of more or less workarounds, but not marking several links at once, sorry.
Perhaps a little macro with an own shorcut or a menu that collects Link URLs one by one into a clipboard list (if setclipboard works again in newer KM versions). Something like Alt-Shift-Middleclick... click... click... click... and at the end you open your text tool and hit Ctrl-V (the most complicated task for this would be to decide for a shortcut ;-))
Or the macro could write the list into a new ini-file, but that has a structure with keys and a values. Or it could write it into a new tab (somewhere I made a macro that does this to show some help instructions, so could look up there how it works).
Or perhaps the native list for All links already helps anything? (View>Links). It could probably be extended to show also the URLs, not just the titles.
Which KM version are you using?
Edited 6 time(s). Last edit at 07/13/2020 02:52PM by siria.
Re: option to copy multiple selected links
Posted by:
JamesD
Date: August 15, 2015 09:47PM
If I correctly understand the need, then this might help. This macro adds an option, "Add link to storage", to the LinkSave menu and to the Tools menu an option called "Send stored links to clipboard". With it, one can add any desired link URL to the list, one at a time, and then move the complete list to the clipboard so it can be pasted.
linkstore.kmm
# K-Meleon Macros (http://kmeleon.sourceforge.net/wiki/index.php?id=MacroLanguage2)
#
# ---------- linkstore.kmm
# ---------- Allow user to store link URLs and on demand copy the store to the clipboard
#
# Version: 1.1 2015_08_15 JamesD
# --------------------------------------------------------------------------------
_linkstore_Add {
macroinfo="Collect links in a list. When finished click menu Tools > Send stored links to clipboard";
$_linkstore_tempclip = getclipboard();
setclipboard( "" );
id(ID_COPY_LINK_LOCATION);
$_linkstore_thislink = getclipboard();
$_linkstore_alllinks = $_linkstore_alllinks."\n". $_linkstore_thislink ;
setclipboard( $_linkstore_tempclip );
}
_linkstore_Send {
setclipboard( $_linkstore_alllinks );
alert(getclipboard(), "Clipboard has:");
}
_linkstore_BuildMenu {
$_linkstore_alllinks = "Selected links list" ;
# add another option to LinkSave menu
setmenu("LinkSave",macro,"Add Link to storage","_linkstore_Add", "&Save Link Target As...");
# add another option to Tools menu
setmenu("&Tools",macro,"Send stored links to clipboard","_linkstore_Send", "Misc");
}
## - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
$OnInit=$OnInit."_linkstore_BuildMenu;";
$macroModules=$macroModules."linkstore;";
Edited 2 time(s). Last edit at 08/15/2015 11:43PM by JamesD.
Re: option to copy multiple selected links
Posted by:
siria
Date: August 15, 2015 11:16PM
Yep, exactly my thought too
Just can't resist... This:
_linkstore_Add {
$_linkstore_tempclip = getclipboard();
setclipboard( "" );
id(ID_COPY_LINK_LOCATION);
$_linkstore_thislink = getclipboard();
$_linkstore_alllinks = $_linkstore_alllinks."\n". $_linkstore_thislink ;
setclipboard( $_linkstore_tempclip );
}
needs no unnecessary complications, just:
_linkstore_Add {
macroinfo="Collect links in a list. When finished click menu Tools > Send stored links to clipboard";
$_linkstore_alllinks = $_linkstore_alllinks."\n". $LinkURL ;
}
Edited 1 time(s). Last edit at 08/15/2015 11:20PM by siria.
Re: option to copy multiple selected links
Posted by:
JamesD
Date: August 15, 2015 11:44PM
siria
I added that line. Thanks
Re: option to copy multiple selected links
Posted by:
siria
Date: August 16, 2015 05:06AM
Yeah, but why not use $LinkURL for collecting, instead of all that clipboard juggling...?
For further improvement the send-macro could offer to reset the stored list and start a new one. The alert box is quite handy for this, just add yes-no-cancel buttons and a question like "Delete stored list now?"
And perhaps prepare a keyboard shortcut (keys free choice up to Wasi as requester :cool
. At least as a howto-note, for users to add themselves to accels.cfg:
# xxxx = macros(_linkstore_Add)
Edited 2 time(s). Last edit at 08/16/2015 09:13AM by siria.
Re: option to copy multiple selected links
Posted by:
JamesD
Date: August 16, 2015 10:18AM
Because I simply did not think about it. Good suggestions. I will have a look at updating the macro.
Re: option to copy multiple selected links
Posted by:
JamesD
Date: August 16, 2015 01:08PM
siria
Using $LinkURL and offering to clear the storage have been added. I am very unsure about keyboard shortcut keys. What would happen if they were used when not on a link? I did not include them.
Thank you for the excellent suggestions.
linkstore.kmm
# K-Meleon Macros (http://kmeleon.sourceforge.net/wiki/index.php?id=MacroLanguage2)
#
# ---------- linkstore.kmm
# ---------- Allow user to store link URLs and, on demand, copy the store to the clipboard
#
# Version: 1.2 2015_08_16 JamesD
# --------------------------------------------------------------------------------
_linkstore_Add {
macroinfo="Collect links in a list. When finished click menu Tools > Send stored links to clipboard";
$_linkstore_alllinks = $_linkstore_alllinks."\n". $LinkURL ;
}
_linkstore_Send {
setclipboard( $_linkstore_alllinks );
alert(getclipboard(), "Clipboard has:");
$_linkstore_reset = confirm("Clear the stored links data now?", "Link Storage", YESNO, QUESTION );
$_linkstore_reset == "YES" ? $_linkstore_alllinks = "Selected links list" : 0;
}
_linkstore_BuildMenu {
$_linkstore_alllinks = "Selected links list" ;
# add another option to LinkSave menu
setmenu("LinkSave",macro,"Add Link to storage","_linkstore_Add", "&Save Link Target As...");
# add another option to Tools menu
setmenu("&Tools",macro,"Send stored links to clipboard","_linkstore_Send", "Misc");
}
## - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
$OnInit=$OnInit."_linkstore_BuildMenu;";
$macroModules=$macroModules."linkstore;";
Re: option to copy multiple selected links
Posted by:
siria
Date: August 16, 2015 02:22PM
Quote
JamesD
I am very unsure about keyboard shortcut keys. What would happen if they were used when not on a link? I did not include them.
Yep same prob here, that's why I want users to choose it themselves
But we can still tell them HOW to do it themselves, by at least adding a hint in the kmm (or even prepare a commented setaccel):
# Keyboard shortcut - HOWTO: choose your preferred keys and add a line to your accels.cfg, using this macro name:
# xxxxxx = macros(_linkstore_Add)
I still remember it took me an endless struggle years ago to just figure out which are the command names in macros! Long, long ago...
Well, and now I'd merge the alert box and the confirmation box into one, and shorten overwritable variables:
_linkstore_Send {
setclipboard( $_linkstore_alllinks );
$_x=getclipboard();
$_x=confirm("Clipboard has ".$_x."\n\n-----------\nClear the stored list now?", "Link list copied / Reset list?", YESNO, QUESTION );
$_x== "YES" ? $_linkstore_alllinks = "selected links list: " : 0;
}
Re: option to copy multiple selected links
Posted by:
JamesD
Date: August 16, 2015 05:00PM
Quote
siria
Quote
JamesD
I am very unsure about keyboard shortcut keys. What would happen if they were used when not on a link? I did not include them.
Yep same prob here, that's why I want users to choose it themselves grinning smiley
But we can still tell them HOW to do it themselves, by at least adding a hint in the kmm (or even prepare a commented setaccel):
My question is not about the user's choice of keys. It is what is in $LinkURL if the keys are pressed and the cursor is not on a link. The menu is only available if the cursor is on a link when the right click occurs.
I had completely forgotten that one can have multiple lines in the message argument of the confirm statement. Another good catch by you.
I tightened up the code a bit more and added one small visual appearance bit to the list title.
I wonder if WasiAzeem has been back to check on this?
linkstore.kmm
# K-Meleon Macros (http://kmeleon.sourceforge.net/wiki/index.php?id=MacroLanguage2)
#
# ---------- linkstore.kmm
# ---------- Allow user to store link URLs and, on demand, copy the store to the clipboard
#
# Version: 1.4 2015_08_16 JamesD
# --------------------------------------------------------------------------------
_linkstore_Add {
macroinfo="Collect links in a list. When finished click menu Tools > Send stored links to clipboard";
$_linkstore_alllinks = $_linkstore_alllinks."\n". $LinkURL ;
}
_linkstore_Send {
setclipboard( $_linkstore_alllinks );
$_x=confirm("Clipboard has the ".getclipboard()."\n\n-----------\nClear the stored list now?", "Link list copied / Reset list?", YESNO, QUESTION );
$_x== "YES" ? $_linkstore_alllinks = "selected links list:\n" : 0;
}
_linkstore_BuildMenu {
$_linkstore_alllinks = "Selected links list:\n" ;
# add another option to LinkSave menu
setmenu("LinkSave",macro,"Add Link to storage","_linkstore_Add", "&Save Link Target As...");
# add another option to Tools menu
setmenu("&Tools",macro,"Send stored links to clipboard","_linkstore_Send", "Misc");
}
## - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
$OnInit=$OnInit."_linkstore_BuildMenu;";
$macroModules=$macroModules."linkstore;";
Re: option to copy multiple selected links
Posted by:
siria
Date: August 16, 2015 05:38PM
Quote
JamesD
My question is not about the user's choice of keys. It is what is in $LinkURL if the keys are pressed and the cursor is not on a link.
It simply is empty. So this macro adds an empty line, which may later indicate to the user that something was wrong.
Another possibility would be to add a check to the macro: $LinkURL=="" ? alert(...)
Thinking about it, a possible check could also include to check for other error possibilities, like empty javascript links if JS is off etc (what whas it again that this usually shows in the statusbar?). Or looking at twitter com, the sign-on button changes the mouse cursor into the link symbol (hand), but there is no link at all...
Anyway, in my opinion a shortcut is just a lot faster for adding a dozen close neighbor links instead of needing the context menu each time and finding the correct line in it each time (my own context menus tend to be slightly extended :cool:
)
(PS: I would have put getclipboard() directly into the confirmation too, but somewhere in the old macrolanguage wiki is a warning to be careful with certain commands directly inside modal window commands (alert/confirm etc.) due to some bug. It may not exist anymore or only affect certain commands, no idea, but since I can never remember the exact conditions, usually just stick to plain variables inside)
Re: option to copy multiple selected links
Posted by:
JamesD
Date: August 16, 2015 09:24PM
OK, I have a control keyset included. I very seldom use them myself. That would require me to remember which keys to use, and at my age remembering is a chancy thing at best.
linkstore.kmm
# K-Meleon Macros (http://kmeleon.sourceforge.net/wiki/index.php?id=MacroLanguage2)
#
# ---------- linkstore.kmm
# ---------- Allow user to store link URLs and, on demand, copy the store to the clipboard
#
# Version: 1.5 2015_08_16 JamesD
# --------------------------------------------------------------------------------
_linkstore_Add {
macroinfo="Collect links in a list. When finished click menu Tools > Send stored links to clipboard";
$LinkURL!=""?$_linkstore_alllinks = $_linkstore_alllinks."\n". $LinkURL : alert("No value for link.") ;
}
_linkstore_Send {
setclipboard( $_linkstore_alllinks );
$_x=confirm("Clipboard has the ".getclipboard()."\n\n-----------\nClear the stored list now?", "Link list copied / Reset list?", YESNO, QUESTION );
$_x== "YES" ? $_linkstore_alllinks = "selected links list:\n" : 0;
}
_linkstore_BuildMenu {
$_linkstore_alllinks = "Selected links list:\n" ;
# add another option to LinkSave menu
setmenu("LinkSave",macro,"Add Link to storage","_linkstore_Add", "&Save Link Target As...");
# add another option to Tools menu
setmenu("&Tools",macro,"Send stored links to clipboard","_linkstore_Send", "Misc");
# set control keys
setaccel( "SHIFT MButton", "macros(_linkstore_Add)" );
}
## - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
$OnInit=$OnInit."_linkstore_BuildMenu;";
$macroModules=$macroModules."linkstore;";
Re: option to copy multiple selected links
Posted by:
siria
Date: August 16, 2015 09:40PM
Hm... alert has no title...
The shortcut is a misunderstanding, I never meant to *activate* it, only have a # line prepared as example! Or the above hint for accels.cfg in a comment line. Basically we fully agree that shortcuts are a bit prone to conflict with others.
Re: option to copy multiple selected links
Posted by:
WasiAzeem
Date: August 17, 2015 02:45AM
Thanks for such a quick and detailed replies. Just saw these and need to read all these, will come back very soon
Re: option to copy multiple selected links
Posted by:
WasiAzeem
Date: August 17, 2015 02:54AM
Quote
siria
Which KM version are you using?
KM 1.6 and KM 75 both, I am in a phase of switching to 75 from 1.6
Re: option to copy multiple selected links
Posted by:
WasiAzeem
Date: August 17, 2015 04:34AM
Many thanks. Versin 1.5 works and it is quite close to what I need, thanks.
Re: option to copy multiple selected links
Posted by:
JamesD
Date: August 17, 2015 05:21PM
WasiAzeem
Glad we could help you. Thank you for your reply.
Re: option to copy multiple selected links
Posted by:
Dorian
Date: August 18, 2015 07:37PM
Using some random bookmarklet, I've made this:
setclipboard(injectJS("(function(){var n_to_open,dl,dll,i,links=''; function linkIsSafe(u) { if (u.substr(0,7)=='mailto:') return false; if (u.substr(0,11)=='javascript:') return false; return true; } n_to_open = 0; dl = document.links; dll = dl.length; if (window.getSelection && window.getSelection().containsNode) { /* mozilla */ for(i=0; i<dll; ++i) { if (window.getSelection().containsNode(dl, true) && linkIsSafe(dl.href)) ++n_to_open; } if (n_to_open) { for(i=0; i<dll; ++i) if (window.getSelection().containsNode(dl, true) && linkIsSafe(dl.href)) links+=dl.href+\""."\\"."n"."\"; } } if (!n_to_open) { for(i = 0; i < dll; ++i) { if (linkIsSafe(dl.href)) ++n_to_open; } if (!n_to_open) alert ('no links'); else { for (i = 0; i < dll; ++i) if (linkIsSafe(dl.href)) links+=dl.href+\""."\\"."n"."\"; } } return links;})()"));
It get links in the selection, or all links if no selection.
Re: option to copy multiple selected links
Posted by:
JamesD
Date: August 19, 2015 12:16PM
OK, I admit that I am lost. Please find me.
What does this mean? This was for all links. I don't know how to select multiple links.
Wed Aug 19 2015 08:10:45 Error: TypeError: Argument 1 of Selection.containsNode does not implement interface Node. Source file: kmeleon Wed Aug 19 2015 08:10:45 Warning: clipboard string length = 0 Source file: C:\Program Files\K-Meleon751_beta\Profiles\s6e1rsk7.default\macros\links2clipb.kmm Line: 12
links2clipb.kmm
# K-Meleon Macros (http://kmeleon.sourceforge.net/wiki/index.php?id=MacroLanguage2)
#
# ---------- links2clipb.kmm
# ---------- Set all/selected links into clipboard
# Version 0.8 2015_08_19 JamesD ( Using Dorians injectJS() statement )
# --------------------------------------------------------------------------------
Linksclip {
setclipboard(injectJS("(function(){var n_to_open,dl,dll,i,links=''; function linkIsSafe(u) { if (u.substr(0,7)=='mailto:') return false; if (u.substr(0,11)=='javascript:') return false; return true; } n_to_open = 0; dl = document.links; dll = dl.length; if (window.getSelection && window.getSelection().containsNode) { /* mozilla */ for(i=0; i<dll; ++i) { if (window.getSelection().containsNode(dl, true) && linkIsSafe(dl.href)) ++n_to_open; } if (n_to_open) { for(i=0; i<dll; ++i) if (window.getSelection().containsNode(dl, true) && linkIsSafe(dl.href)) links+=dl.href+\""."\\"."n"."\"; } } if (!n_to_open) { for(i = 0; i < dll; ++i) { if (linkIsSafe(dl.href)) ++n_to_open; } if (!n_to_open) alert ('no links'); else { for (i = 0; i < dll; ++i) if (linkIsSafe(dl.href)) links+=dl.href+\""."\\"."n"."\"; } } return links;})()"));
# test only
$_ll = length(getclipboard() ) ;
logmsg("clipboard string length = ". $_ll, warning);
}
_link2clipb_SetAccels {
setaccel( "CTRL SHIFT L", "macros(Linksclip)" );
}
## - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
$OnInit=$OnInit."_link2clipb_SetAccels;";
$macroModules=$macroModules."link2clipb;";
Edited 1 time(s). Last edit at 08/19/2015 12:18PM by JamesD.
Re: option to copy multiple selected links
Posted by:
Dorian
Date: August 20, 2015 04:26PM
Quote
JamesD
What does this mean? This was for all links. I don't know how to select multiple links.
You don't select link. It only search for links in the selected text.
Quote
JamesD
Wed Aug 19 2015 08:10:45 Error: TypeError: Argument 1 of Selection.containsNode does not implement interface Node.
You get it all the time or on specific pages?
Re: option to copy multiple selected links
Posted by:
JamesD
Date: August 20, 2015 05:30PM
Quote
Dorian
You don't select link. It only search for links in the selected text.
Thanks. Now I understand that.
Quote
Dorian
You get it all the time or on specific pages?
I just got the same messages for the area 'Home/News' through 'Development' at the top of this thread. So that is two times. Once with no selection and once with a selection.
Re: option to copy multiple selected links
Posted by:
Wasi Azeem
Date: February 26, 2016 09:31AM
I love K-Meleon and I love you guys.
Re: option to copy multiple selected links
Posted by:
siria
Date: July 13, 2020 05:52AM
Quote
Dorian
Using some random bookmarklet, I've made this:
setclipboard(injectJS("(function(){var n_to_open,dl,dll,i,links=''; function linkIsSafe(u) { if (u.substr(0,7)=='mailto:') return false; if (u.substr(0,11)=='javascript:') return false; return true; } n_to_open = 0; dl = document.links; dll = dl.length; if (window.getSelection && window.getSelection().containsNode) { /* mozilla */ for(i=0; i<dll; ++i) { if (window.getSelection().containsNode(dl, true) && linkIsSafe(dl.href)) ++n_to_open; } if (n_to_open) { for(i=0; i<dll; ++i) if (window.getSelection().containsNode(dl, true) && linkIsSafe(dl.href)) links+=dl.href+\""."\\"."n"."\"; } } if (!n_to_open) { for(i = 0; i < dll; ++i) { if (linkIsSafe(dl.href)) ++n_to_open; } if (!n_to_open) alert ('no links'); else { for (i = 0; i < dll; ++i) if (linkIsSafe(dl.href)) links+=dl.href+\""."\\"."n"."\"; } } return links;})()"));
It get links in the selection, or all links if no selection.
Quote
DorianYou get it all the time or on specific pages?Quote
JamesD
Wed Aug 19 2015 08:10:45 Error: TypeError: Argument 1 of Selection.containsNode does not implement interface Node.
Just came across this randomly again, and wondered how that selection thing works in JS. But the code was too confusing, so started fiddling with it... as usual... oh well ;-) After awhile realized: the plain bookmarklet works if copied from a quote post, but the macro had a bug. Obviously the forum was culprit: it's eaten all [ i ] in the visible code! Only the posts 'source' code has the full original. Old prob, happened a couple times before, am meanwhile aware of that trick.
But couldn't stop there, wanted a visible output, and an option for names, and... (the usual again ;-)
Have now made an update of this second macro (links2clip):
The updated macro links2clip-v2 is now available above, on top of this page, in the second post. And more description about it. For example this output box can also be suppressed.
Re: option to copy multiple selected links
Posted by:
JohnHell
Date: July 13, 2020 01:40PM
Quote
siria
Obviously the forum was culprit: it's eaten all [ i ] in the visible code!
Thanks for this new unfixable Phorum nightmare to my dreams.
Thankfully, can be escaped any square bracket by adding a backslash [i] in the post edit or prior to posting [code]
setclipboard(injectJS("(function(){var n_to_open,dl,dll,i,links=''; function linkIsSafe(u) { if (u.substr(0,7)=='mailto:') return false; if (u.substr(0,11)=='javascript:') return false; return true; } n_to_open = 0; dl = document.links; dll = dl.length; if (window.getSelection && window.getSelection().containsNode) { /* mozilla */ for(i=0; i<dll; ++i) { if (window.getSelection().containsNode(dl[i], true) && linkIsSafe(dl[i].href)) ++n_to_open; } if (n_to_open) { for(i=0; i<dll; ++i) if (window.getSelection().containsNode(dl[i], true) && linkIsSafe(dl[i].href)) links+=dl[i].href+\""."\\"."n"."\"; } } if (!n_to_open) { for(i = 0; i < dll; ++i) { if (linkIsSafe(dl[i].href)) ++n_to_open; } if (!n_to_open) alert ('no links'); else { for (i = 0; i < dll; ++i) if (linkIsSafe(dl[i].href)) links+=dl[i].href+\""."\\"."n"."\"; } } return links;})()"));
Edited 1 time(s). Last edit at 07/13/2020 01:40PM by JohnHell.
Re: option to copy multiple selected links
Posted by:
siria
Date: July 13, 2020 02:17PM
Quote
JohnHellQuote
siria
Obviously the forum was culprit: it has eaten all [ i ] in the visible code!
Thanks for this new unfixable Phorum nightmare to my dreams.
Thankfully, can be escaped any square bracket by adding a backslash [i] in the post edit or prior to posting [code]
HA - great trick! Another just perfect solution, finally
But then again, this creates another catch: now the post's original code, as seen when hitting the "quote" button, is not original anymore and will be 'buggy'
And the other 'almost perfect' workaround, to check "Disable BBcode" and "Disable Smileys" in the header above, does keep the original code original AND the visible output correct too.
But also has a killer catch : stuff like [quote] or [code] or smilies or text colors don't work either, and will show up literally
Oh well, guess we'll have to consider in each single case which escape method to use. For my previous sentence here, your backslash method \[i] is just perfect, thanks. While for posting larger code blocks, they should probably be posted with the checkboxes above marked. Was aware of that before, but wanted to include the quotes, and was in a hurry. Next time may post such code blocks alone in a single post, and rest of talk in a second post.
(_howto_ HowTo post CODE in forum, escape square brackets, smilies and other bbcode syntax)
Edited 3 time(s). Last edit at 07/13/2020 02:27PM by siria.
Re: option to copy multiple selected links
Posted by:
JohnHell
Date: July 13, 2020 03:57PM
Code blocks could be used escaped (after all, forum users shouldn't quote to copy, but copy directly the code block) and offer a file for download (those of us who can attach), even though it doubles the post size and wishing SourceForge keeps forgiving us for the space usage.
That is the reason it is a new Phorum script nightmare
Edited 1 time(s). Last edit at 07/13/2020 03:58PM by JohnHell.
English